SHIFTKEY

VB6와 비교해서 .Net의 콤보박스의 확장된 기능중으로  ValueMember, DisplayMember를 들수 있는데

이넘들의 활용에 관해서 간단한 팁을 소개 할까합니다. 콤보박스에 CODE/VALUE 데이터를 세팅하는 방법과 콤보박스에서 특정값을 찾아서 선택되어진 상태로 만드는 소스입니다.

보통 콤보박스에는 코드네임을 보여주고 선택한 코드네임을 기준으로 따로 저장해 두었던 코드를 매칭하여 DB에 저장하기 때문에 불편한 점이 많았는데 이런한 불편을 해소하기 위한 좋은 방법인거 같습니다.

먼저 알아두어야 할점은 ComboBox.Items 속성은 ComboBox.ObjectCollection Type 이기 때문에 어떤값을 할당하느냐에 따라서 참조할 때의 방법도 달라 진다는 점 입니다.

1.  DataTable 객체를 콤보박스에 바인딩

        Dim Mcmd As New System.Data.OleDb.OleDbCommand
        Mcmd.Connection = Mcnn                           ' 오픈된 커낵션
        Mcmd.CommandType = CommandType.Text              ' CODE/CODENAME 자료를 조회
        Mcmd.CommandText = "SELECT Format(ID,'0000') AS ID, USERNAME FROM Users ORDER BY ID "
        Dim dr As System.Data.OleDb.OleDbDataReader
        dr = Mcmd.ExecuteReader
        Dim dt As New DataTable("oleDT")
        dt.Load(dr)                                      ' DataReader에서 DataTable로 자료로딩
        cb.DataSource = dt                               ' DataTable 객체를 콤보박스에 바인딩
        cb.DisplayMember = dt.Columns(1).ToString        ' 콤보박스에 보여주는 값
        cb.ValueMember = dt.Columns(0).ToString          ' 콤보박스에서 참조하는 값
        dr.Close()                                       ' DataReader 닫기
        Mcmd.Dispose()
        cb.SelectedIndex = GetListIndex(dt, 0, uid)      ' 특정값의 인덱스를 찾는 함수 호출

    '이경우 사용자가 콤보박스에서 다른 값을 선택했다면 다음처럼 값을 구합니다.
    Private Sub cbUserName_SelectedIndexChanged(ByVal sender As System.Object,  _
             ByVal e As System.EventArgs) Handles cbUserName.SelectedIndexChanged
             Dim tmpUser As String = cbUserName.SelectedValue
    End Sub

    ' 데이타 테이블에서 주어진 문자열로 시작하는 행의 인덱스를 반환 하는 함수입니다.
    ' 위 쿼리에서는 값이 2개 지만 참조되는 값이 여럿이라도 문제가 없습니다.
    Public Function GetListIndex(ByVal lst As DataTable, ByVal col As Integer, _
                                 ByVal findStr As String) As Integer
        Dim tarStr As String
        Dim intleng As Integer = findStr.Length
        For i As Integer = 0 To lst.Rows.Count - 1
            Dim dr As DataRow = lst.Rows(i)
            tarStr = dr(col).ToString()
            If findStr = tarStr.Substring(0, intleng) Then Return i
        Next i
        Return 0
    End Function

    ' 소스의 다른 위치에서 콤보박스를 특정값이 선택되도록...
        ComboBox.SelectedIndex = GetListIndex(ComboBox.DataSource, 1, "00123")
 

2. DB가 아니라 Name, Value 쌍의 문자열 이면

   Name, Value 쌍을 가진 클래스의 ArrayList를 사용하는 방법이 유용

        Dim cbNameValues As New ArrayList                   ' ArrayList 선언 및 인스턴싱
        cbNameValues.Add(New NameValue("강아지", "001"))    ' 사용자정의형 클래스를 맴버로 추가해줌
        cbNameValues.Add(New NameValue("고양이", "002"))
        cbNameValues.Add(New NameValue("망아지", "003"))
        cbNameValues.Add(New NameValue("지렁이", "004"))
        cbNameValues.Add(New NameValue("멍청이", "005"))
        cb.DataSource = cbNameValues                       ' 데이터소스에 컬랙션을 지정
        cb.DisplayMember = "Name"                          ' 아이템이 되는 클래스의 한 속성
        cb.ValueMember = "Value"                        
        cb.SelectedIndex = GetListIndex(cbNameValues, 1, uid)   ' 특정값이 현재 선택되도록


   ' 이  경우 에도 값의 참조는 cbUserName.SelectedValue 형태를 사용합니다.

   ' Name Value 쌍을 가진 ArrayList에서 주어진 문자열로 시작하는 행의 인덱스를 반환
    Public Function GetListIndex(ByVal lst As ArrayList, ByVal col As Integer, _
                                 ByVal findStr As String) As Integer
        Dim tarStr As String
        Dim intleng As Integer = findStr.Length
        For i As Integer = 0 To lst.Count - 1
            Dim NewNameValue As NameValue = lst.Item(i)
            If col = 0 Then
                tarStr = NewNameValue.Name
            Else
                tarStr = NewNameValue.Value
            End If
            If findStr = tarStr.Substring(0, intleng) Then Return i
        Next i
        Return 0
    End Function

    ' 소스의 다른 위치에서 콤보박스를 특정값이 선택되도록...
        ComboBox.SelectedIndex = GetListIndex(ComboBox.DataSource, 1, "00123")



    Public Class NameValue            ' 사용자 정의 클래스 
        Private m_Name As String
        Private m_Value As String
        Public Sub New(ByVal pName As String, ByVal pValue As String)
            m_Name = pName
            m_Value = pValue
        End Sub
        Public Property Name() As String
            Get
                Return m_Name
            End Get
            Set(ByVal value As String)
                m_Name = value
            End Set
        End Property
        Public Property Value() As String
            Get
                Return m_Value
            End Get
            Set(ByVal value As String)
                m_Value = value
            End Set
        End Property
    End Class
 

3. 고전적인 방법도 물론 유용합니다.

        Dim Mcmd As New System.Data.OleDb.OleDbCommand
        Mcmd.Connection = Mcnn
        Mcmd.CommandType = CommandType.Text
        Mcmd.CommandText = "SELECT Format(ID,'0000') AS ID, USERNAME FROM Users ORDER BY ID "
        Dim dr As System.Data.OleDb.OleDbDataReader
        cb.Items.Clear()                                ' 기존 아이템을 전부 삭제
        dr = Mcmd.ExecuteReader
        While dr.Read
            cb.Items.Add(dr.GetValue(0) & " " & dr.GetValue(1))
        End While
        dr.Close()
        Mcmd.Dispose()
        cb.SelectedIndex = GetListIndex(cb, uid)       ' 특정 문자열로 시작하는 인덱스를 구한다면.

    '이경우 사용자가 콤보박스에서 다른 값을 선택했다면 다음처럼 값을 구합니다.
    Private Sub cbUserName_SelectedIndexChanged(ByVal sender As System.Object,  _
             ByVal e As System.EventArgs) Handles cbUserName.SelectedIndexChanged
             Dim tmpUser As String = cbUserName.Text
    End Sub

    ' 콤보박스에서 주어진 문자로 시작하는 인덱스를 반환
    ' 반환값 : 오류시 < 0 , 자료없슴 = 0, 주어진문자로 시작하는 처음 인덱스 반환
    Public Function GetListIndex(ByVal lst As ComboBox, ByVal findStr As String) As Integer
        Dim tarStr As String
        Dim intleng As Integer = findStr.Length
        For i As Integer = 0 To lst.Items.Count - 1
            tarStr = lst.Items(i).ToString
            If findStr = tarStr.Substring(0, intleng) Then Return i
        Next i
        Return 0
    End Function
 

출처 : http://www.devpia.com/maeul/contents/d ··· page%3D1

* 3개 이상의 데이터를 컨트롤 해야 한다면 콤보박스에 dt를 DataSource로 넣었기 때문에 "cbobox.DataSource.Rows(1).Item(2).ToString" 이런식으로 가져다 쓰면 된다.

콤보박스의 SelectedValueChanged 이벤트를 이용하면 sender.SelectedIndex 로 현재 선택 위치를 알 수 있다.